' Az űrlapra helyezzünk el a következő objektumot:
' Button1: parancsgomb

' A futtatás előtt a projekt tulajdonságainál a References panelen
' kattintsunk az Add gombra, majd a COM panelen keressük meg
' a Word osztálykönyvtárát:
'    MS Office 2010 esetén: Microsoft Word 14.0 Object Library
'    MS Office 2013 esetén: Microsoft Word 15.0 Object Library
' Kattintsunk a jelölőnégyzetre, majd az OK gombra!

' A Példa.doc fájlt másoljuk a saját Dokumentumok mappánkba.

Imports Microsoft.Office.Interop.Word

Public Class Form1

    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        ' 1. ===================================================
        ' A Word-alkalmazás létrehozása:
        Dim Word As New Application
        '               Nem kötelező Word-nek nevezni az objektumot! :)
        ' A Word megnyitása:
        Word = New Application
        ' Az ablak megjelenítése az asztalon:
        ' (Célszerű megjeleníteni, hogy hiba esetén kézzel be lehessen zárni!)
        Word.Visible = True
        ' 2. ===================================================
        ' A Word-dokumentum (fájl) elérési útja
        '     (itt a felhasználó saját Dokumentumok mappáját adjuk meg):
        Dim Fájl As String = My.Computer.FileSystem.SpecialDirectories.MyDocuments & "\Példa.doc"
        '     Lehetne például: Dim Fájl As String = "c:\Példa.doc" :)        ' A fálj megnyitása:
        Word.Documents.Open(Fájl)
        ' 3. ===================================================
        ' Megnyitás után a kurzor a szöveg elején helyezkedik el,
        ' így elvégezzük a formátumbeállítást és a szöveg beillesztését.
        ' Átváltunk félkövér betűstílusra:
        Word.Selection.Font.Bold = True
        ' Bekapcsoljuk a középre igazítást:
        Word.Selection.ParagraphFormat.Alignment = WdParagraphAlignment.wdAlignParagraphCenter
        ' Beillesztjük a szöveget:
        Word.Selection.TypeText("A programhibák típusai")
        ' 4. ===================================================
        ' Enter beillesztése:
        Word.Selection.TypeParagraph()
        ' Kikapcsoljuk a félkövér betűstílust:
        Word.Selection.Font.Bold = False
        ' Kikapcsoljuk a középre igazítást:
        Word.Selection.ParagraphFormat.Alignment = WdParagraphAlignment.wdAlignParagraphLeft
        ' 5. ===================================================
        ' Lejjebb megyünk 7 sorral (az első paraméter alapértelmezett értéke a sor):
        Word.Selection.MoveDown(, 7)
        ' Elmegyünk a sor végére:
        Word.Selection.EndKey()
        ' 6. ===================================================
        ' Átváltunk dőlt betűstílusra:
        Word.Selection.Font.Italic = True
        ' Beírjuk a szöveget:
        Word.Selection.TypeText("hibák")
        ' Kikapcsoljuk a dőlt betűstílust:
        Word.Selection.Font.Italic = False
        ' 7. ===================================================
        ' A dokumentum elejére állítjuk a kurzort (Ctrl+Home):
        Word.Selection.HomeKey(WdUnits.wdStory)
        ' 8. ===================================================
        ' Beállítjuk a keresés/csere tulajdonságait:
        '    (ha biztosan tudjuk, hogy nincsenek előzetes beállítások,
        '     akkor elegendő lenne csak azokat a tulajdonságokat
        '     megadni, amiket módosítani akarunk)
        With Word.Selection.Find
            ' Az előző keresés/csere formázási beállítások törlése:
            .ClearFormatting()
            .Replacement.ClearFormatting()
            ' Keresett szöveg:
            .Text = "hiba"
            ' Csere erre:
            .Replacement.Text = "hiba"
            ' Csere formátuma:
            .Replacement.Font.Bold = True
            .Replacement.Font.Color = WdColor.wdColorRed
            ' Keresés előre:
            .Forward = True
            ' Folytassa a szöveg elejéről, ha elértünk a végére
            '   (csak akkor kell, ha a kurzor nem a szöveg elején helyezkedik el):
            .Wrap = WdFindWrap.wdFindStop
            ' Keresés/csere formázással:
            .Format = True
            ' Kis- és nagybetű megkülönböztetése:
            .MatchCase = False
            ' Csak ha ez a teljes szó:
            .MatchWholeWord = False
            ' Nem használunk helyettesítő karaktereket:
            .MatchWildcards = False
        End With
        ' A keresés/csere végrehajtása
        ' (a paramétereket már előzőleg beállítottuk):
        Word.Selection.Find.Execute(, , , , , , , , , , WdReplace.wdReplaceAll)
        ' 9. ===================================================
        ' A dokumentum mentése, bezárása:
        Word.Documents.Save()
        Word.Documents.Close()
        ' 10. ==================================================
        ' Kilépés a Word-ből:
        Word.Quit()
        ' 11. ==================================================
        ' Az objektumváltozó felszabadítása:
        Word = Nothing
        MessageBox.Show("Kész a fájl.")
    End Sub
End Class