' Az űrlapra helyezzünk el a következő objektumot:
' Button1: parancsgomb

' A futtatás előtt a projekt tulajdonságainál a References panelen
' kattintsunk az Add gombra, majd a COM panelen keressük meg az
' Excel osztálykönyvtárát:
'    MS Office 2010 esetén: Microsoft Excel 14.0 Object Library
'    MS Office 2013 esetén: Microsoft Excel 15.0 Object Library
' Kattintsunk a jelölőnégyzetre, majd az OK gombra!

Imports Microsoft.Office.Interop.Excel

Public Class Form1

    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        Dim I As Integer
        ' 1. ===================================================
        ' Excel-alkalmazás deklarálása:
        Dim Excel As Application
        '            Nem kötelező Excelnek nevezni az objektumot! :)
        ' Az Excel-alkalmazás létrehozása (megnyitása):
        Excel = New Application
        ' Az ablak megjelenítése az asztalon:
        ' (Célszerű megjeleníteni, hogy hiba esetén kézzel be lehessen zárni!)
        Excel.Visible = True
        ' 2. ===================================================
        ' Az így megnyitott alkalmazásban nem jön létre munkafüzet,
        ' külön utasítással kell létrehozni:
        Excel.Workbooks.Add()
        ' 3. ===================================================
        ' A munkafüzet mentése
        ' A fájl elérési útja (hozzáférési jog!)
        '      (itt a felhasználó saját Dokumentumok mappáját adjuk meg):
        Dim Fájl As String = My.Computer.FileSystem.SpecialDirectories.MyDocuments & "\Fibonacci.xlsx"
        ' Lehetne például: Dim Fájl As String = "c:\Fibonacci.xlsx" stb.
        ' A fájlt mentése:
        Excel.ActiveWorkbook.SaveAs(Fájl)
        ' A munkafüzet bezárása (csak a példa kedvéért):
        Excel.ActiveWorkbook.Close()
        ' Kilépés az Excelből (csak azért, hogy majd bemutassuk a megnyitását):
        Excel.Quit()
        ' Az objektumváltozó felszabadítása:
        Excel = Nothing
        ' 4. ===================================================
        ' Az Excel megnyitása:
        Excel = New Application
        Excel.Visible = True
        ' A munkafüzet megnyitása
        Excel.Workbooks.Open(Fájl)
        ' 5. ===================================================
        ' A kiválasztott munkalap kijelölése:
        Dim Munkalap As Worksheet
        Munkalap = Excel.Worksheets("Munka1")
        '      vagy: Munkalap = Excel.Worksheets(1)
        ' 6. ===================================================
        ' Írás a 2. sor 1. oszlopába (A2): 
        Munkalap.Cells(2, 1).Value = "Fibonacci-sorozat"
        ' Írás a 2. sor 3. oszlopába (C2):
        Munkalap.Cells(2, 3).Value = 1
        ' 7. ===================================================
        ' Így is lehet írni egy cellába (C3)
        '    (először ki kell választani a munkalapot):
        Excel.Sheets("Munka1").Select()
        Excel.Range("C3").Select()
        Excel.ActiveCell.Formula = 1
        ' Képlet beírása (a Cells helyett használható a Range is):
        Munkalap.Cells(4, 3).Formula = "=C2+C3"
        '     Lekérdezésnél a Value az értéket, a Formula a képletet adja vissza.
        ' 8. ===================================================
        ' Képlet beírása sor/oszlop-típusú hivatkozásokkal:
        For I = 5 To 10
            Munkalap.Cells(I, 3).FormulaR1C1 = "=SUM(R[-2]C[0]:R[-1]C[0])"
            ' a szögletes zárójel a relatív hivatkozásra utal
            '     a 0 elhagyható: R[-2]C:R[-1]C
            ' abszolút hivatkozás például: R2C1 (megfelel $A$2-nek)
        Next
        ' 9. ===================================================
        ' Cellák formázása:
        Excel.Range("C2:C10").Select()
        ' Félkövér karakterek:
        Excel.Selection.Font.Bold = True
        ' Piros színű karakterek (az Excel színpalettát használ):
        Excel.Selection.Font.ColorIndex = 3
        ' 10. ==================================================
        ' Az aktív cella visszaállása A1-re:
        Excel.Range("A1").Select()
        ' A munkafüzet mentése:
        Excel.ActiveWorkbook.Save()
        ' Kilépés az Excelből:
        Excel.Quit()
        ' Az objektumváltozók felszabadítása:
        Munkalap = Nothing
        Excel = Nothing
        MessageBox.Show("Kész a fájl.")
    End Sub
End Class